Signatur dynamisch erzeugen

Alessandro Banzer's Blog

Wednesday, 12. May 2010

Signatur dynamisch erzeugen

Es gibt oft Vorteile wieso kein Roaming-Profil verwendet wird. Recht mĂĽhsam bei den lokalen Profilen ist es aber, dass die Signatur unter Microsoft Outlook jedes mal neu erzeugt werden muss. Um dies per Login-Script zu automatisieren, habe ich ein kleines Script geschrieben. Dies sucht sich die Informationen aus dem AD und schreibt diese in ein HTM Dokument.

  1. '
  2. ' Create_Signatures.vbs
  3. '
  4. ' 2010 Banzer Alessandro
  5. '
  6.  
  7. ' Benutzername und Domäne abfragen
  8. On Error Resume Next
  9. Set objNW = WScript.CreateObject("WScript.Network")
  10. strUserDomain = objNW.UserDomain
  11. strUserName = objNW.UserName
  12. Set objNW = Nothing
  13.  
  14. ' WinNT Namen in AD Namen ĂĽbersetzen
  15. ' siehe http://www.rlmueller.net/NameTranslateFAQ.htm
  16. Const ADS_NAME_INITTYPE_GC = 3
  17. Const ADS_NAME_TYPE_NT4 = 3
  18. Const ADS_NAME_TYPE_1779 = 1
  19.  
  20. Set objTrans = CreateObject("NameTranslate")
  21. objTrans.Init ADS_NAME_INITTYPE_GC, ""
  22. objTrans.Set ADS_NAME_TYPE_NT4, strUserDomain & "\" & strUserName
  23. strUserDN = objTrans.Get(ADS_NAME_TYPE_1779)
  24. Set objTrans = Nothing
  25.  
  26. ' Benutzer Objekt aus den AD holen und Attribute in Variablen speichern
  27. ' siehe http://www.rlmueller.net/References/ADUCProperties.xls
  28. Set objUser = GetObject("LDAP://" & strUserDN)
  29. strFirstname = objUser.givenName
  30. strLastname = objUser.sn
  31. strJobTitle = objUser.title
  32. strDepartment = objUser.Department
  33. strStreet = objUser.StreetAddress
  34. strPostalCode = objUser.PostalCode
  35. strCity = objUser.l
  36. strPhone = objUser.telephonenumber
  37. strFax = objUser.facsimiletelephonenumber
  38. strMobile = objUser.mobile
  39. strEmail = objUser.mail
  40. strWeb = objUser.wWWHomePage
  41. strCompany = objUser.company
  42. strCountry = objUser.co
  43. strCountryC = objUser.c
  44. Set objUser = Nothing
  45.  
  46.  
  47.  
  48. ' Testen, ob Verzeichnis schon vorhanden und wenn nötig anlegen.
  49. Set WshShell = WScript.CreateObject("WScript.Shell")
  50. strAppData = WshShell.RegRead("HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\AppData")
  51. Set WshShell = Nothing
  52.  
  53. Set objFS = CreateObject("Scripting.FileSystemObject")
  54. strSignatureDir = strAppData & "\Microsoft\Signatures"
  55. If Not objFS.FolderExists(strSignatureDir) Then
  56.     objFS.CreateFolder(strSignatureDir)
  57. End If
  58.  
  59. ' Signatur als HTM Datei Schreiben
  60. Set objFile = objFS.CreateTextFile(strSignatureDir & "\" & strUserName & ".htm")
  61. objFile.WriteLine("<!DOCTYPE HTML PUBLIC '-//W3C//DTD HTML 4.0 Transitional//EN'>")
  62. objFile.WriteLine("<HTML xmlns:o = 'urn:schemas-microsoft-com:office:office'><HEAD><TITLE>" & strFirstname & " " & strLastname & " Signatur</TITLE>")
  63. objFile.WriteLine("<META content='text/html; charset=windows-1252' http-equiv=Content-Type>")
  64. objFile.WriteLine("<META name=GENERATOR content='MSHTML 8.00.7600.16490'></HEAD>")
  65. objFile.WriteLine("<BODY><DIV align=left><FONT size=1 face=Arial>")
  66. objFile.WriteLine("<u>______________________________________</u><BR>&nbsp;")
  67. objFile.WriteLine("<BR>" & strFirstname & " " & strLastname)
  68. If strDepartment = "" Then
  69.         objFile.WriteLine("<BR>" & strJobTitle)
  70. Else
  71.         objFile.WriteLine("<BR>" & strJobTitle & ", " & strDepartment)
  72. End If
  73. objFile.WriteLine("<BR>&nbsp;<BR>" & strCompany)
  74. objFile.WriteLine("<BR>" & strStreet)
  75. objFile.WriteLine("<BR>" & strCountryC & " " & strPostalCode & " " & strCity & ", " & strCountry)
  76. If Not strMobile = "" Then
  77.         objFile.WriteLine("<BR>Tel. " & strPhone & "")
  78.         objFile.WriteLine("<BR>Mobile " & strMobile & "")
  79.         objFile.WriteLine("<BR>Fax " & strFax & "")
  80. Else
  81.         objFile.WriteLine("<BR>Tel. " & RTrim(strPhone) & ", Fax " & strFax )
  82. End If
  83. objFile.WriteLine("<BR>E-Mail <a href='mailto:" & strEmail & "'>" & LCase(strEmail) & "</a>")
  84. objFile.WriteLine("<BR>Internet <a href='http://" & strWeb & "'>" & strWeb & "</a>")
  85. objFile.WriteLine("<BR><u>______________________________________</u></FONT></DIV></BODY></HTML>")
  86.  
  87. Set objFile = Nothing
  88. Set objFS = Nothing
  89.  
  90. ' end of file

Posted by
Alessandro Banzer
at 08:56 | No comments | No Trackbacks
Trackbacks
Trackback specific URI for this entry
No Trackbacks
Comments
Display comments as (Linear | Threaded)
No comments
Add Comment
Enclosing asterisks marks text as bold (*word*), underscore are made via _word_.
Standard emoticons like :-) and ;-) are converted to images.

To prevent automated Bots from commentspamming, please enter the string you see in the image below in the appropriate input box. Your comment will only be submitted if the strings match. Please ensure that your browser supports and accepts cookies, or your comment cannot be verified correctly.
CAPTCHA

You can use [geshi lang=lang_name [,ln={y|n}]][/geshi] tags to embed source code snippets.
 
   
 

ĂĽber mich

Alessandro Banzer
Computer Scientist
22 Jahre
alessandro[at]admins.li
www.helium.li

Calendar

Back September '10
Mo Tu We Th Fr Sa Su
Mon September 6 2010
    1 2 3 4 5
6 7 8 9 10 11 12
13 14 15 16 17 18 19
20 21 22 23 24 25 26
27 28 29 30      

kategorien



All categories

blogroll

Alex Hladik Annubis Blog witze-sind-witzig.de infoblog.li

buttons

BlogPingR.de - Blog Ping-Dienst, Blogmonitor blog-o-rama.de Blogverzeichnis - Blog Verzeichnis bloggerei.de Bloggeramt.de Blogs www.beliebtestewebseite.de Blog Top Liste - by TopBlogs.de

blog abonnieren

Archives

Statistiken

Letzter Artikel: 2010-08-27 11:53
212 Artikel wurden geschrieben
28 Kommentare wurden abgegeben
0 Besucher online

Blog Administration

Open login screen